Open Source Flipper Zero, Thread, Matter, and Zigbee on ESP32, Arduino go Zephyr, and more!

0:00:00 / -

Watch now on YouTube Watch now

Shooting Aliens With Ps2 Joystick

Made by talofer99 / Games & Gaming

About the project

A true blast from the past

Project info

Difficulty: Moderate

Platforms: Arduino

Estimated time: 1 hour

License: GNU General Public License, version 3 or later (GPL3+)

Items used in this project

Hardware components

	ps2 male connector	x 1
	Analog joystick (Generic)	x 1
	Arduino Nano R3	x 1

Software apps and online services

Arduino IDE

Story

It’s if this project did not want to come to life, it’s a joystick that act like a PS2 keyboard, which was supposed to be an easy build since I done a few PS2 projects in the past.

I was mid project, when I noticed that there is a glitch in the system once in a while one of the keys will get “stuck” For example, I would release the fire button and yet the firing in the game will continue. and this sent me down the rabbit hole, and this project was on the table for over 2 months now, It got to the point I thought of just letting it go, but let’s start at the beginning. At the end of the ZORK episode I mentioned that I want to turn this bundle of wires to a proper board.

2 days later I came across the TTGO ESP32 VGA, It’s an esp32, SD card, usb for the esp, VGA output, 2 PS2inputs, sound jack and it even has a connector for battery. They are considerably cheap, so I just ordered one. And when it arrived the first thing I done was to run ZORK on it. I immediately noticed a big difference. When the game is loaded on my board the VGA had interference or noise, on this board, it’s just crisp. I did had to change the setting of the VGA pinout in the code, but it was a very simple change. One thing I’m not a big fan of on this board, is the SD connector, I get the cost and size constrain, but this is an accident waiting to happen. So to reduce the chance of destroying the SD I printed out this great case. https://www.thingiverse.com/thing:4570375

Makes the SD somewhat more protected. Do note this is meant for the 1.4 version of the board. When I posted this a lot of people commented that I should have used a joystick for playing. Which made me come up with the idea to make a ps2 joystick that will act like a keyboard.

I done projects with PS2 in the past so I was prepared. I had a cable ready for it, some code and most important old library of ps2dev.

I created a simple code that will send a press and release of the key “1” every1 second, In order for the code to work well I made several adjustments to the old library and to the code itself. But eventually I got it working. At this point I turned to create the joystick part of the project, to start it going I used the 8 button breakout I created for the Port manipulation video, since I really do not like using buttons on breadboards. They tend to jump out.

I connected the last 4 buttons, while actually using just 3 out of them, 2 for directions and one for the space so we can shoot thus aliens. And the last wire is ground the buttons are pulled up in the software. The logic for the code was simple. Make sure we debounce the buttons.

Then if we take this case for example, to send the keyboard right key command to a host, we need to first send 0xe0 that mark the next byte is a special key and in our case its 0x74. Also note that if the button state is HIGH, which means the button was released, we also send the oxf0 in the middle to signal it’s a key release and not a key press. I will explain later why the command is placing the data into a buffer.

Now all happy and ready to play, I uploaded the space invaders example to the TTGO, uploaded the new code to the nano and was good to go. This is when the glitch was found. And it is also the point I stoppeddocumenting the process I spent hours debugging the issue and at some point just gave up. The setup was sitting on the table for few good weeks, then one day I just powered it up, this time powering the joystick from the esp. It’s only when I got to level 3, I noticed there were no glitches. Happy with that I completed the project – not with ease – as I said it did not want to come to life. The case was designed in fusion 360. This set of analog joysticks were scraped from a joystick long time ago

This is the nano you seen before, this is the PS2connector, and all of this is soldered on a PCB that is glued to the based. I will pull the nano out of its socket. The wiring is underneath, going to the connector and the analog joystick. You can use both of the joystick buttons for firing. And there are 2 pulldown resistors, since the buttons are connected to the 5V and you cannot pulldown programmatically. And off course lots of hot glue to keep everything in place

Code

Untitled file

#include <ps2dev.h>    //Emulate a PS/2 device
PS2dev keyboard(4, 3); //clock (green), data (white)

// button related
#define BUT_RIGHT 0
#define BUT_LEFT 1
#define BUT_SPACE 2

#define BUT_PRESS 0
#define BUT_RELEASE 1
#define NUMBUTTON 3

// joyStick relater
#define JOYSTICK_X A0
#define JOYSTICK_Y A1
#define JOYSTICK_LB 5
#define JOYSTICK_RB 6

int joyStickXCenter = 0;
int joyStickYCenter = 0;
byte joyStickDebounceGap = 10;

// Variables will change:
int buttonState[NUMBUTTON];      // the current button state
int lastButtonState[NUMBUTTON]; // the previous reading from the input pin
unsigned long lastDebounceTime[NUMBUTTON]; // the last time the output pin was toggled
unsigned long debounceDelay = 50;    // the debounce time; increase if the output flickers
byte currentCheckedButton = 0;


#define ps2DataBufferSIZE 7
byte ps2DataBuffer[ps2DataBufferSIZE];
byte ps2DataBufferHead = 0;
byte ps2DataBufferTail = 0;
byte messageByteSent = 0;


void insertToBuffer(byte value)
{
  ps2DataBuffer[ps2DataBufferHead] = value;
  ps2DataBufferHead = (ps2DataBufferHead + 1) % ps2DataBufferSIZE;
}

byte pullFromBuffer(byte * readValue)
{
  byte availableBuffer = 0;
  if (ps2DataBufferHead != ps2DataBufferTail)
  {
    *readValue = ps2DataBuffer[ps2DataBufferTail];
    availableBuffer = 1;
  }

  return availableBuffer;
}

void moveBufferToNext()
{
  // move
  ps2DataBufferTail = (ps2DataBufferTail + 1) % ps2DataBufferSIZE;
}



void setup()
{
  keyboard.keyboard_init();
  Serial.begin(115200);
  Serial.println("System started");
  pinMode(LED_BUILTIN, OUTPUT);
  initJoyStick();
}

void loop()
{
  //Handle PS2 communication and react to keyboard led change
  //This should be done at least once each 10ms
  unsigned char leds;
  unsigned char c;  //char stores data recieved from computer for KBD
  if (keyboard.available())
  {
    int reply = keyboard.read(&c);
    if (!reply)
      keyboard.keyboard_reply(c, &leds);
    // on resend
    if (c == 0xFE)
    {
      Serial.println("System RESEND");
      //messageByteSent = 0;
    } //end if
  } //end if

  if (messageByteSent)
  {
    moveBufferToNext();
    messageByteSent = 0;
  } // end if

  //handle buffer
  byte currentDataToSend;
  if (pullFromBuffer(&currentDataToSend))
  {
    messageByteSent = 1;
    keyboard.write(currentDataToSend);
  } // end if


  // process joystick
  processJoyStick();

}

void initJoyStick()
{
  byte counter = 10;
  unsigned long accumalteX = 0;
  unsigned long accumalteY = 0;
  for (int i = 0; i < counter; i++)
  {
    accumalteX += analogRead(JOYSTICK_X);
    delay(1);
    accumalteY += analogRead(JOYSTICK_Y);
    delay(1);
  }

  joyStickXCenter = int(accumalteX / counter);
  joyStickYCenter = int(accumalteY / counter);
  //Serial.println("joyStickXCenter - " + String(joyStickXCenter));
  //Serial.println("joyStickYCenter - " + String(joyStickYCenter));

  // set up buttons
  for (byte i = 0; i < NUMBUTTON; i++)
  {
    // reset variables
    buttonState[i] = HIGH;
    lastButtonState[i] = HIGH;
    lastDebounceTime[i] = 0;
  } //end for

  // press button
  pinMode(JOYSTICK_LB, INPUT);
  pinMode(JOYSTICK_RB, INPUT);
}



void processJoyStick()
{
  int reading = 1;
  int readJoyStickX = 0;

  switch (currentCheckedButton)
  {
    case BUT_RIGHT:

      readJoyStickX = analogRead(JOYSTICK_X);
      if (readJoyStickX > joyStickDebounceGap + joyStickXCenter)
        reading = 0;
      break;

    case BUT_LEFT:

      readJoyStickX = analogRead(JOYSTICK_X);
      if (readJoyStickX < joyStickXCenter - joyStickDebounceGap)
        reading = 0;
      break;
    case BUT_SPACE:
      // read the state of the switch into a local variable:
      reading = !(digitalRead(JOYSTICK_LB) | digitalRead(JOYSTICK_RB));
      break;
    default:
      Serial.println("WTF ???");
  }


  // If the switch changed, due to noise or pressing:
  if (reading != lastButtonState[currentCheckedButton]) {
    // reset the debouncing timer
    lastDebounceTime[currentCheckedButton] = millis();
  } //end if

  if ((millis() - lastDebounceTime[currentCheckedButton]) > debounceDelay) {
    // whatever the reading is at, it's been there for longer than the debounce
    // delay, so take it as the actual current state:

    // if the button state has changed:
    if (reading != buttonState[currentCheckedButton]) {
      buttonState[currentCheckedButton] = reading; //match

      // flag and buffer
      switch (currentCheckedButton)
      {
        case BUT_RIGHT:
          //Serial.println("BR");
          insertToBuffer(0xe0);
          if (buttonState[currentCheckedButton] == HIGH)
            insertToBuffer(0xf0);
          insertToBuffer(0x74);
          break;
        case BUT_LEFT:
          //Serial.println("BL");
          insertToBuffer(0xe0);
          if (buttonState[currentCheckedButton] == HIGH)
            insertToBuffer(0xf0);
          insertToBuffer(0x6B);
          break;
        case BUT_SPACE:
          //Serial.println("BS");
          if (buttonState[currentCheckedButton] == HIGH)
            insertToBuffer(0xf0);
          insertToBuffer(0x29);
          break;
      } //end switch
    } //end if
  } //end if

  // save the reading. Next time through the loop, it'll be the lastButtonState:
  lastButtonState[currentCheckedButton] = reading;

  // move to next button for next loop
  currentCheckedButton = (currentCheckedButton + 1) % NUMBUTTON;

}

Credits

talofer99

Maker @ heart

Shop

Project Hub

Video

Blog

Shop home

3D printing

Single Board Computers

Development kits

Sensors

Internet of things

Robotics

Accessories

Product of the Week

Electromaker Educator

The Electromaker Show

The Electromaker Podcast

Shooting Aliens With Ps2 Joystick

About the project

Project info