Open Source Flipper Zero, Thread, Matter, and Zigbee on ESP32, Arduino go Zephyr, and more!

0:00:00 / -

Watch now on YouTube Watch now

How To Create Ble-wifi Range Extender For T-skin

Made by The Tactigon / Communication / Home Automation / Robotics / Wearables / IoT

About the project

We wanted to increase the communication range of the Tactigon Skin so we could use it over longer distances than BLE can offer.

Project info

Difficulty: Moderate

Platforms: Adafruit, NodeMCU, Raspberry Pi

Estimated time: 1 hour

License: GNU General Public License, version 3 or later (GPL3+)

Items used in this project

Hardware components

	Tiny Breadboard	x 1
	Breakout Kit for Raspberry Pi Model A+&B+&2	x 1
	Raspberry Pi 3 Model B	x 1
	Tactigon Skin	x 1

Software apps and online services

Arduino IDE

Story

Introduction

Hello! We made this project to extend the range of communication of the Tactigon Skin (also T-Skin) to use it over longer distances that the ones that Bluetooth Low Energy can offer. To achieve this goal, we used the UDP protocol over Wi-Fi to send data from the Tactigon Skin to a PC, using a Raspberry Pi Zero W. Wi-Fi capabilities for the Tactigon Skin have been added by using a NodeMCU with a BLE module.

Hardware Architecture

Lots of devices are connected here, so a little picture can help:

Because the Tactigon Skin does not have Wi-Fi onboard we had to use a NodeMCU with a BLE module to relay data to the Raspberry Pi Zero W. The UDP packets are sent over a private network hosted by the RPi, which is configured as an access point, so that there’s no need to use public networks.

To configure the access point follow this link: Configure Access Point Mode

Software Architecture

Now that we know how all nodes are connected, we can examine how each one works.

BLE to UDP node

BLE to UDP node

The T-Skin gather information about its sensors (gyroscope, accelerometers, etc.) and create a packet that will be sent to the NodeMCU via BLE.

Here you can see how the T-Skin gathers the data:

T_QUAT qMeter;
T_QData qData;
  
qData = qMeter.getQs();
roll = radToDegree(qData.roll - rollZero);
pitch = radToDegree(qData.pitch - pitchZero);
yaw = radToDegree(qData.yaw - yawZero);

First we declare qMeter and qData, objects based on the T_QUAT and T_QData class. This will contain all the quaternions data from the gyroscope, then we read the actual data with qMeter.getQs(). Now we can separate the roll, pitch and yaw values and store them into the respective variables.

After that the received data are relayed to the Raspberry Pi Zero W using the UDP protocol.

WiFiUDP Udp;
unsigned int UDP_Port = 5000;
char* UDP_IP = "192.168.4.1";
char PacketBuffer[1024];
  
Udp.beginPacket(UDP_IP, UDP_Port);
Udp.write(PacketBuffer);
Udp.endPacket();

Every time an entire data packet is received we begin creating a packet for the UDP communication, specifying the IP address and the port of the receiver. Then we write on the communication line the data and close the packet sending procedure.

Note that in case of a connection failure the NodeMCU is configured in order to try to reconnect as soon as possible.

UDP to VCOM

In this setup the Raspberry Pi Zero is configured as a Gadget Device, allowing it to be identified by a PC as a Serial Port device. To configure the device follow this link: Serial Gadget Mode Configuration

Once the UDP packets are received, an always running Python script takes that data and forwards it to the Virtual Serial Port of the Pi. On the PC, opening a serial monitor to the corresponding COM allows you to see the data that have been gathered by the T-Skin at the beginning of the communication chain.

Here's an example:

Conclusions

With this project we reached our goal to use the Tactigon Skin over longer distances. Performance wise the range have been increased from 3 ~ 4 meters with BLE only to a staggering 40+ meters with the use of Wi-Fi communication.

The main limitations with this implementation are the actual maximum range of the Raspberry Pi Zero W Wi-Fi antenna and the overcrowdedness of the 2.4 Ghz spectrum. The second problem could be avoided, if necessary, with the use of alternative LPWAN protocols such as LoRa and SigFox.

This communication range extender can be used to enable so many projects using the T-skin, breaking the barrier of distances. Some example might include remote control a robot in situations like bomb disposal and search and rescue missions.

Code

RPi_Tactigon_Extender.py

This code will automatically run at bootup on the Raspberry Pi Zero W.

#!/usr/bin/env python
#UDP SERVER CODE
#To run this script at boot you have te add the following to the /etc/rc.local file in sudo mode
#sudo python /path_to_this_script/script_name.py
#before the exit 0 directive
import os
import sys
import socket
import serial
import time

UDP_PORT = 5000
UDP_IP = '192.168.4.1' #IP address of the machine to whick this script will run
#small delay to ensure that everithing started up
time.sleep(10)

port = serial.Serial("/dev/ttyGS0", baudrate=115200, timeout=0.1)

sock = socket.socket(socket.AF_INET, socket.SOCK_DGRAM)
sock.bind((UDP_IP, UDP_PORT))

while ((port.in_waiting) <= 0):
    data, addr = sock.recvfrom(1024) #store received data
    #print(data) #for debug
    port.write(data + '\n') #write received data from UDP to the emulated serial port
#if the input buffer of the serial port is NOT empty that means that the shutdown command has been received from the PC
os.system("shutdown now -h")

BLEtoUDP.ino

This code is flashed onto the NodeMCU.

//SENDER
#include <ESP8266WiFi.h>
#include <WiFiUdp.h>

//UDP handle
WiFiUDP Udp;
unsigned int UDP_Port = 5000;
char* UDP_IP = "192.168.4.1"; //IP address of the RECEIVER
char PacketBuffer[1024]; //Buffer used for UDP data

//Wifi handle
const char* ssid = "YOUR_SSID"; 
const char* password = "YOUR_PASSWORD";
IPAddress ip(192, 168, 4, 2); //set a static IP for this device
IPAddress gateway(192, 168, 4, 1);
IPAddress subnet(255, 255, 255, 0);

bool flag = false; //to handle complete read of BLE data
int count = 0; //counter for checking correct length of received buffer from BLE, starts from 0 to 19

void setup() {
	memset(&PacketBuffer, (char)0, 1024); //set all buffer to 0
	pinMode(LED_BUILTIN, OUTPUT); //LOW = WiFi connected; HIGH = WiFi not connected
	digitalWrite(LED_BUILTIN, HIGH);
	Serial.begin(115200); //BLE serial
	WiFi.config(ip, gateway, subnet);
	WiFi.mode(WIFI_STA); //station mode
	WiFi.begin(ssid, password);
	Serial.println();
	Serial.print("Wait for WiFi");
	//wait for wireless connection
	while (WiFi.status() != WL_CONNECTED) {
		delay(500);
		Serial.print(".");
	}
	digitalWrite(LED_BUILTIN, LOW);
	Serial.println("");
	Serial.println("WiFi connected");
	Serial.println("IP address: " + WiFi.localIP().toString());
	Serial.println();
	Udp.begin(UDP_Port); //initialize UDP
}

void loop() {
	//if wireless connection drops, try to reconnect to it
	while (WiFi.status() != WL_CONNECTED) {
		digitalWrite(LED_BUILTIN, HIGH);
		delay(500);
		Serial.print(".");
	}

	digitalWrite(LED_BUILTIN, LOW);
	if (Serial.available()) {
		//read one char at the time and store it to che progressive 'count' position in the buffer array
		Serial.read(&PacketBuffer[count], 1);
		//checking for carriage return and line feed chars 
		//replace carriage return (if for any reasons is present) with whitespace to avoid complications in the buffer processing by the receiver
		if (PacketBuffer[count] == '\r') PacketBuffer[count] = ' '; 
		else if (PacketBuffer[count] == '\n') {
			//at this point the one buffer from BLE serial is completely processed
			PacketBuffer[count] = (char)0; 
			count = 0; //reset counter
			flag = true; //complete data
		}
		else {
			//increment counter for next char read
			count++; 
		}
	}

	if (flag) {
		//start send data from [1] and not [0] due to how data is sent by the T-skin.
		//the data in [0] is treated by a serial read as a terminator char (char)0.
		//if this data ends up in the buffer that we send the calid data after that char will be ignored
		//sending data from 2nd element is less time consuming that shifting all buffer
		//Serial.println(&PacketBuffer[1]); //for debug
		//here we send via UDP the data from BLE
		Udp.beginPacket(UDP_IP, UDP_Port);
		Udp.write(&PacketBuffer[1]);
		Udp.endPacket();
		flag = false; //reset flag for next buffer
		memset(PacketBuffer, (char)0, 1024); //set all buffer to 0
	}
}

Credits

The Tactigon

The Tactigon is a brand of Next Industries Milano. Next Industries is a born of a passion to develop devices and sensors fit for Iot Technology. Our team is made of incredible experts in movement detection for big structural monitoring systems, software development and wearable device.

Shop

Project Hub

Video

Blog

Shop home

3D printing

Single Board Computers

Development kits

Sensors

Internet of things

Robotics

Accessories

Product of the Week

Electromaker Educator

The Electromaker Show

The Electromaker Podcast

How To Create Ble-wifi Range Extender For T-skin

About the project

Project info

Items used in this project

Hardware components

Software apps and online services

Story

Introduction

Hardware Architecture

Software Architecture

Conclusions

Code

RPi_Tactigon_Extender.py

BLEtoUDP.ino

Credits

The Tactigon

Leave your feedback...

Shop

Project Hub

Video

Blog

Shop home

3D printing

Single Board Computers

Development kits

Sensors

Internet of things

Robotics

Accessories

Product of the Week

Electromaker Educator

The Electromaker Show

The Electromaker Podcast

How To Create Ble-wifi Range Extender For T-skin

About the project

Project info

Items used in this project

Hardware components

Software apps and online services

Story

Introduction

Hardware Architecture

Software Architecture

Conclusions

Code

RPi_Tactigon_Extender.py

BLEtoUDP.ino

Credits

The Tactigon

Leave your feedback...

Related products