Amazing Open Source Raspberry Pi Pico 2 Synth, Cutting Edge Power over Skin Research, and much more!

0:00:00 / -

Watch now on YouTube Watch now

Galaxy Dog Jacket

Made by 8BitsAndAByte / 3D Printing / Animals / Lights / Wearables

About the project

A galaxy themed jacket made for an earthbound dog!

Project info

Difficulty: Moderate

Platforms: Adafruit

Estimated time: 2 days

License: Creative Commons Attribution-NonCommercial-ShareAlike CC BY-NC-SA version 4.0 or later (CC BY-NC-SA 4+)

Items used in this project

Hardware components

	Adafruit Feather (nRF52 Bluefruit LE - nRF52832)	x 1
	Adafruit NeoPixel Ring: WS2812 5050 RGB LED	x 1
	Lipo battery 3.7V	x 1
	Smartphone with Bluetooth and the Adafruit Bluefruit LE Connect app (optional)	x 1

Hand tools and fabrication machines

	Needle & thread	x 1
	3D Printer (generic)	x 1
	Sewing machine	x 1
	Hook-and-loop fastener	x 1
	Fabrics for the dog jacket as required by the pattern, depending on the size of the dog	x 1
	Dog jacket pattern (Simplicity Sewing Pattern S9035 Quilted Dog Coats)	x 1

Story

Overview

Below an overview of the content:

Project video
Dog Jacket
Hardware
Feather Setup and Bluetooth App
Controlling the NeoPixels
Detachable Patch
3D Print
Result!

Project Video

A galaxy themed jacket made for an earthbound dog!

Dog Jacket

The first step is either buying or making a jacket for your dog to wear, to add the electronics to. In this case we opted to sew our own jacket because we wanted to challenge ourselves a bit, improve our sewing skills and pick an awesome galaxy themed fabric!

We chose the Simplicity Sewing Pattern S9035 Quilted Dog Coats, as the pattern looked nice yet easy enough for someone with intermediate sewing skills (it has a difficulty rating of 2/5).

Measure your dog to determine the size of the coat and the amount of fabric needed. Prewash all of your fabrics the way you intend to wash the final project before you cut and start sewing to avoid shrinkage of your dog coat!

Follow the directions of the pattern to sew the dog coat. This is easier said than done, as we’ve experienced, so good luck!

Hardware

The dog coat is looking good, but we still can’t find our dog in the dark. The perfect thing to add would be some lights, so let’s do just that!

For the hardware, we opted for the Adafruit Feather (nRF52 Bluefruit LE - nRF52832) because it’s small and lightweight. At 5.7 grams they advertise it as being as light as a (large?) feather. For the lights, we chose a NeoPixel Ring with 12 lights, compact yet very bright. A 500mAh 3.7V LiPo battery provides the power.

We wired all the components as shown in the Fritzing diagram above.

Feather Setup and Bluetooth App

On to the next part, getting the hardware to do stuff! The idea is to connect the Adafruit Feather to the Adafruit Bluefruit LE Connect app on a smartphone and pick the colour of the NeoPixels via the app.

But first things first, we need to set up the Adafruit Feather to work with the Arduino IDE by following this guide provided by Adafruit.

Next up is uploading the controller sketch to the Feather. This example sketch can be found in the Arduino IDE by going to File > Examples > Adafruit Bluefruit nRF52 Libraries > Peripheral > controller

With this sketch uploaded to the Feather, you can now connect it to the smartphone Bluefruit app by following the steps outlined in this guide.

Controlling the NeoPixels

Once the Feather and app are connected, the Feather can already receive a number of Bluetooth messages from the app, including a colour! To send a colour to the Feather, open the Bluefruit app and connect to your feather. In the menu, go to Controller > Color Picker. The moment you pick a colour via the colour wheel and press the select button, the message containing the colour is sent to your feather, pretty neat right?

All we have to do is add some code to control the NeoPixels and change their colour when the Bluetooth message arrives. The full code to do this is added in attachment!

Detachable Patch

To keep the dog jacket washable, because, you know, dogs... we’re going to add the electronics to a seperate patch of fabric. A strip of hook-and-loop on both the back of the dog jacket and on the patch ensures that the lights can stick on the coat and can be taken off when it’s inevitably in need of a wash.

We chose to make a quilted patch of fabric in the shape of an octagon in the same fabrics as the dog jacket, with blue galaxy fabric at the top and black fleece on the bottom. With the batting on the inside of the patch, it’s quite stable and sturdy enough to add the electronics.

3D Print

There are a million ways to add the electronics to the patch of fabric, including stuff like sewable electronics. We 3D printed a planet to hold all the components and diffuse the lights at the same time.

The bottom part of the holder fits all the hardware and has holes in the bottom so it can be manually sewn onto the patch of fabric in four places. The top of the holder is attached with some self adhesive hook-and-loop tape, so it can easily be opened to turn on the Feather and charge the LiPo battery.

The 3D files are added in attachment. We printed the planet holders in a transparent filament with a light infill of 5%.

Result!

Last but not least, assemble all the parts, place the planet on the dog jacket and get your dog to wear it! Doesn’t that look amazing?

Two things we’ve noticed since using it:

An on/off switch on the Feather would be really practical, it would be great to add one.
When the dog shakes itself, the electronics can and will fly off… We didn’t think of this until it actually happened, you’ve been warned!

Schematics, diagrams and documents

Wiring

CAD, enclosures and custom parts

Planet Top

Go to download

Planet Bottom

Go to download

Code

packetParser.cpp

#include <string.h>
#include <Arduino.h>
#include <bluefruit.h>


#define PACKET_ACC_LEN                  (15)
#define PACKET_GYRO_LEN                 (15)
#define PACKET_MAG_LEN                  (15)
#define PACKET_QUAT_LEN                 (19)
#define PACKET_BUTTON_LEN               (5)
#define PACKET_COLOR_LEN                (6)
#define PACKET_LOCATION_LEN             (15)

//    READ_BUFSIZE            Size of the read buffer for incoming packets
#define READ_BUFSIZE                    (20)


/* Buffer to hold incoming characters */
uint8_t packetbuffer[READ_BUFSIZE+1];

/**************************************************************************/
/*!
    @brief  Casts the four bytes at the specified address to a float
*/
/**************************************************************************/
float parsefloat(uint8_t *buffer) 
{
  float f;
  memcpy(&f, buffer, 4);
  return f;
}

/**************************************************************************/
/*! 
    @brief  Prints a hexadecimal value in plain characters
    @param  data      Pointer to the byte data
    @param  numBytes  Data length in bytes
*/
/**************************************************************************/
void printHex(const uint8_t * data, const uint32_t numBytes)
{
  uint32_t szPos;
  for (szPos=0; szPos < numBytes; szPos++) 
  {
    Serial.print(F("0x"));
    // Append leading 0 for small values
    if (data[szPos] <= 0xF)
    {
      Serial.print(F("0"));
      Serial.print(data[szPos] & 0xf, HEX);
    }
    else
    {
      Serial.print(data[szPos] & 0xff, HEX);
    }
    // Add a trailing space if appropriate
    if ((numBytes > 1) && (szPos != numBytes - 1))
    {
      Serial.print(F(" "));
    }
  }
  Serial.println();
}

/**************************************************************************/
/*!
    @brief  Waits for incoming data and parses it
*/
/**************************************************************************/
uint8_t readPacket(BLEUart *ble_uart, uint16_t timeout) 
{
  uint16_t origtimeout = timeout, replyidx = 0;

  memset(packetbuffer, 0, READ_BUFSIZE);

  while (timeout--) {
    if (replyidx >= 20) break;
    if ((packetbuffer[1] == 'A') && (replyidx == PACKET_ACC_LEN))
      break;
    if ((packetbuffer[1] == 'G') && (replyidx == PACKET_GYRO_LEN))
      break;
    if ((packetbuffer[1] == 'M') && (replyidx == PACKET_MAG_LEN))
      break;
    if ((packetbuffer[1] == 'Q') && (replyidx == PACKET_QUAT_LEN))
      break;
    if ((packetbuffer[1] == 'B') && (replyidx == PACKET_BUTTON_LEN))
      break;
    if ((packetbuffer[1] == 'C') && (replyidx == PACKET_COLOR_LEN))
      break;
    if ((packetbuffer[1] == 'L') && (replyidx == PACKET_LOCATION_LEN))
      break;

    while (ble_uart->available()) {
      char c =  ble_uart->read();
      if (c == '!') {
        replyidx = 0;
      }
      packetbuffer[replyidx] = c;
      replyidx++;
      timeout = origtimeout;
    }
    
    if (timeout == 0) break;
    delay(1);
  }

  packetbuffer[replyidx] = 0;  // null term

  if (!replyidx)  // no data or timeout 
    return 0;
  if (packetbuffer[0] != '!')  // doesn't start with '!' packet beginning
    return 0;
  
  // check checksum!
  uint8_t xsum = 0;
  uint8_t checksum = packetbuffer[replyidx-1];
  
  for (uint8_t i=0; i<replyidx-1; i++) {
    xsum += packetbuffer[i];
  }
  xsum = ~xsum;

  // Throw an error message if the checksum's don't match
  if (xsum != checksum)
  {
    Serial.print("Checksum mismatch in packet : ");
    printHex(packetbuffer, replyidx+1);
    return 0;
  }
  
  // checksum passed!
  return replyidx;
}

controllerNeopixelDogJacket.ino

/*********************************************************************
 This is an example for our nRF52 based Bluefruit LE modules

 Pick one up today in the adafruit shop!

 Adafruit invests time and resources providing this open source code,
 please support Adafruit and open-source hardware by purchasing
 products from Adafruit!

 MIT license, check LICENSE for more information
 All text above, and the splash screen below must be included in
 any redistribution
*********************************************************************/

#include <bluefruit.h>

// Adafruit NeoPixel library

#include <Adafruit_NeoPixel.h>
#ifdef __AVR__
 #include <avr/power.h> // Required for 16 MHz Adafruit Trinket
#endif

// Which pin on the Arduino is connected to the NeoPixels?
#define PIN        29 // On Trinket or Gemma, suggest changing this to 1

// How many NeoPixels are attached to the Arduino?
#define NUMPIXELS 12 // Popular NeoPixel ring size

// When setting up the NeoPixel library, we tell it how many pixels,
// and which pin to use to send signals. Note that for older NeoPixel
// strips you might need to change the third parameter -- see the
// strandtest example for more information on possible values.
Adafruit_NeoPixel pixels(NUMPIXELS, PIN, NEO_GRB + NEO_KHZ800);

#define DELAYVAL 500 // Time (in milliseconds) to pause between pixels

// OTA DFU service
BLEDfu bledfu;

// Uart over BLE service
BLEUart bleuart;

// Function prototypes for packetparser.cpp
uint8_t readPacket (BLEUart *ble_uart, uint16_t timeout);
float   parsefloat (uint8_t *buffer);
void    printHex   (const uint8_t * data, const uint32_t numBytes);

// Packet buffer
extern uint8_t packetbuffer[];

void setup(void)
{
  Serial.begin(115200);
  while ( !Serial ) delay(10);   // for nrf52840 with native usb

  Serial.println(F("Adafruit Bluefruit52 Controller App Example"));
  Serial.println(F("-------------------------------------------"));

  Bluefruit.begin();
  Bluefruit.setTxPower(4);    // Check bluefruit.h for supported values
  Bluefruit.setName("Bluefruit52");

  // To be consistent OTA DFU should be added first if it exists
  bledfu.begin();

  // Configure and start the BLE Uart service
  bleuart.begin();

  // Set up and start advertising
  startAdv();

  pixels.begin(); 

  Serial.println(F("Please use Adafruit Bluefruit LE app to connect in Controller mode"));
  Serial.println(F("Then activate/use the sensors, color picker, game controller, etc!"));
  Serial.println();  
}

void startAdv(void)
{
  // Advertising packet
  Bluefruit.Advertising.addFlags(BLE_GAP_ADV_FLAGS_LE_ONLY_GENERAL_DISC_MODE);
  Bluefruit.Advertising.addTxPower();
  
  // Include the BLE UART (AKA 'NUS') 128-bit UUID
  Bluefruit.Advertising.addService(bleuart);

  // Secondary Scan Response packet (optional)
  // Since there is no room for 'Name' in Advertising packet
  Bluefruit.ScanResponse.addName();

  /* Start Advertising
   * - Enable auto advertising if disconnected
   * - Interval:  fast mode = 20 ms, slow mode = 152.5 ms
   * - Timeout for fast mode is 30 seconds
   * - Start(timeout) with timeout = 0 will advertise forever (until connected)
   * 
   * For recommended advertising interval
   * https://developer.apple.com/library/content/qa/qa1931/_index.html   
   */
  Bluefruit.Advertising.restartOnDisconnect(true);
  Bluefruit.Advertising.setInterval(32, 244);    // in unit of 0.625 ms
  Bluefruit.Advertising.setFastTimeout(30);      // number of seconds in fast mode
  Bluefruit.Advertising.start(0);                // 0 = Don't stop advertising after n seconds  
}

/**************************************************************************/
/*!
    @brief  Constantly poll for new command or response data
*/
/**************************************************************************/
void loop(void)
{
  // Wait for new data to arrive
  uint8_t len = readPacket(&bleuart, 500);
  if (len == 0) return;

  // Got a packet!
  // printHex(packetbuffer, len);

  // Color
  if (packetbuffer[1] == 'C') {
    uint8_t red = packetbuffer[2];
    uint8_t green = packetbuffer[3];
    uint8_t blue = packetbuffer[4];
    Serial.print ("RGB #");
    if (red < 0x10) Serial.print("0");
    Serial.print(red, HEX);
    if (green < 0x10) Serial.print("0");
    Serial.print(green, HEX);
    if (blue < 0x10) Serial.print("0");
    Serial.println(blue, HEX);

    // For the number of NeoPixels 
    // Set the colour to the colour received via Bluetooth
    for (int i = 0; i < NUMPIXELS; i++){
      pixels.setPixelColor(i, pixels.Color(red, green, blue));
    }
    // Update the NeoPixels 
    pixels.show();
  }

  // Buttons
  if (packetbuffer[1] == 'B') {
    uint8_t buttnum = packetbuffer[2] - '0';
    boolean pressed = packetbuffer[3] - '0';
    Serial.print ("Button "); Serial.print(buttnum);
    if (pressed) {
      Serial.println(" pressed");
    } else {
      Serial.println(" released");
    }
  }

  // GPS Location
  if (packetbuffer[1] == 'L') {
    float lat, lon, alt;
    lat = parsefloat(packetbuffer+2);
    lon = parsefloat(packetbuffer+6);
    alt = parsefloat(packetbuffer+10);
    Serial.print("GPS Location\t");
    Serial.print("Lat: "); Serial.print(lat, 4); // 4 digits of precision!
    Serial.print('\t');
    Serial.print("Lon: "); Serial.print(lon, 4); // 4 digits of precision!
    Serial.print('\t');
    Serial.print(alt, 4); Serial.println(" meters");
  }

  // Accelerometer
  if (packetbuffer[1] == 'A') {
    float x, y, z;
    x = parsefloat(packetbuffer+2);
    y = parsefloat(packetbuffer+6);
    z = parsefloat(packetbuffer+10);
    Serial.print("Accel\t");
    Serial.print(x); Serial.print('\t');
    Serial.print(y); Serial.print('\t');
    Serial.print(z); Serial.println();
  }

  // Magnetometer
  if (packetbuffer[1] == 'M') {
    float x, y, z;
    x = parsefloat(packetbuffer+2);
    y = parsefloat(packetbuffer+6);
    z = parsefloat(packetbuffer+10);
    Serial.print("Mag\t");
    Serial.print(x); Serial.print('\t');
    Serial.print(y); Serial.print('\t');
    Serial.print(z); Serial.println();
  }

  // Gyroscope
  if (packetbuffer[1] == 'G') {
    float x, y, z;
    x = parsefloat(packetbuffer+2);
    y = parsefloat(packetbuffer+6);
    z = parsefloat(packetbuffer+10);
    Serial.print("Gyro\t");
    Serial.print(x); Serial.print('\t');
    Serial.print(y); Serial.print('\t');
    Serial.print(z); Serial.println();
  }

  // Quaternions
  if (packetbuffer[1] == 'Q') {
    float x, y, z, w;
    x = parsefloat(packetbuffer+2);
    y = parsefloat(packetbuffer+6);
    z = parsefloat(packetbuffer+10);
    w = parsefloat(packetbuffer+14);
    Serial.print("Quat\t");
    Serial.print(x); Serial.print('\t');
    Serial.print(y); Serial.print('\t');
    Serial.print(z); Serial.print('\t');
    Serial.print(w); Serial.println();
  }
}

Credits

8BitsAndAByte

We’re Dane & Nicole, two makers that create tremendously terrible tech, which we happily share with you on our channel! https://www.youtube.com/c/8bitsandabyte

Shop

Project Hub

Video

Blog

Shop home

3D printing

Single Board Computers

Development kits

Sensors

Internet of things

Robotics

Accessories

Product of the Week

Electromaker Educator

The Electromaker Show

The Electromaker Podcast

Galaxy Dog Jacket

About the project

Project info