Amazing Open Source Raspberry Pi Pico 2 Synth, Cutting Edge Power over Skin Research, and much more!

0:00:00 / -

Watch now on YouTube Watch now

Build A Granular Synthesiser Using The Arduino

Made by CharisCat / Music / Upcycling / IoT

About the project

This project will teach you how to build the hardware for your own DIY synthesiser! The Auduino code (first written by Peter Knight) creates two triangle waves with adjustable frequency and decay, which combine to create noises via a granular synthesis. I added CV controls to the circuit, making it modular.

Project info

Difficulty: Moderate

Platforms: Arduino

Estimated time: 2 hours

License: GNU General Public License, version 3 or later (GPL3+)

Items used in this project

Hardware components

	Stripboard At least 17x20 dots, but more space means you could add more upgrades later	x 1
	Arduino Nano	x 1
	Wire I used recycled wire from inside an old cable	x 1
	100k Potentiometers Can be anywhere between 10-100k, just make sure they're the same	x 5
	6.35mm Audio Jacks If you have a modular system that uses 3.5mm, those work fine too.	x 4
	LED I used purple, use whatever you like!	x 4
	Light Dependent Resistors	x 3
	560Ohm Resistor (I used a 4.7k resistor on my external LED to dim it, as I used ultrabright LEDs)	x 4
	Wooden Enclosure I used a biscuit box, anything that fits the components in will work!	x 1

View all

Software apps and online services

Arduino

Hand tools and fabrication machines

	Soldering Iron	x 1
	Wire Strippers	x 1
	Computer that can run Arduino software	x 1

Story

Hi, I'm Charis Cat - A musician, video producer, and general tinkerer from Devon in the UK. I started this project after spending a lot of time online staring at other peoples modular synthesisers. I ended up diving deep into electronics research, and decided that it would be fun (and cost-efficient) to try to build my own! This is the first module I have created, and it makes some gorgeous ambient sounds (which you can hear in my video).

The Auduino works by creating two triangle waves with pitch and decay knobs, which you turn and tune to form interesting harmonics. The singular knob to the left of my Auduino affects the frequency of the repetition of a grain of this noise - this means that you can tune it to a wide variety of pitches from deep bass growls to high pitched ambient squeals. The code which runs it is relatively simple, and very well noted, and therefore this makes a great project for someone perhaps looking into changing the code up too!

1. Breadboarding the Basic Circuit

Before I started trying to come up with a permanent version of the circuit, I made sure to test everything out on a breadboard. This allowed me to think about my CV controls, which first started as an experimental light theremin control.

- All the potentiometers are connected to 5v on one side, and ground on the other side.

- The centre pin on each potentiometer is connected to (respectively) Arduinos analog inputs 0, 1, 2, 3, and 4.

- The audio out jack is connected to ground from its ground pin, and to the Arduinos digital out 3 from its signal pin(s).

- The LED is connected to ground from its ground pin, and to the Arduinos digital out 13 from it's positive pin.

2. Creating the Enclosure

To create the enclosure for my Auduino, all I did was drill some appropriately sized holes into a wooden box. I also used sticky back velcro to stick the stripboard to the bottom of the box, to stop it from rolling around during use. I also painted the top of the wood using acrylic paint, and 3D printed some 'Moog style potentiometer knobs' from Thingiverse.

You could use anything as your enclosure! I would be interested in seeing any cool experimental enclosures people come up with for this thing!

3. Making a homemade CV Vactrol

In my circuit, I have included some very basic DIY Vactrols to give this thing CV inputs. These isolate the circuit from the input, and stop any issues if you were to plug something into it with the wrong voltage somehow. They also add a bit of 'ambient niceness' to the CV control!

For this bit, you'll need 3 of your LEDs, and your 3 Light Dependent Resistors (LDRs).

- If your LED has a curved top, you can file it flat using sandpaper or a nail file. This allows it to get more solid contact between it and the LDR when you stick them together.

- Place the two pieces facing each other, and wrap them up in electrical tape (or use heat shrink, if you're more prepared). One tip is to cut the negative leg on the LED even shorter, so that you can tell which side of the vactrol is which.

- Try to make them as isolated as possible, so that no external light gets in.

The way which you add these to the circuit is to bridge them over the potentiometers.

- The positive leg of the LDR receives power from the Arduino.

- The negative leg of the LDR goes to the same signal pin as the potentiometer you want it to affect (I chose the main grain frequency (Analog pin 0), and the two individual wave pitches (Analog pins 3 and 1)).

- The positive leg of the LED is connected to the signal pin on the audio jack, and will be powered by the CV that you put into it.

- The ground led of the LED is connected to the ground on its corresponding audio jack. (not the ground for the rest of the circuit, this is providing the isolation)

4. Wiring and Soldering

Once you have mounted everything into your enclosure, made your vactrols, and wired everything together - it is time to solder. I did this in sections so that I could remember what I was doing.

5. Playing your Synth!

Now, take some time to play with the awesome sounds that the Auduino can make!

Thanks so much for reading, there is further visual information in my youtube video - and also links to others work I found useful along this journey! If you need any further help, I am happy to answer any comments!

CAD, enclosures and custom parts

Moog Style Potentiometers

Go to download

Code

Auduino Code - Peter Knight

https://code.google.com/archive/p/tinkerit/wikis/Auduino.wiki

// Auduino, the Lo-Fi granular synthesiser
//
// by Peter Knight, Tinker.it http://tinker.it
//
// Help:      http://code.google.com/p/tinkerit/wiki/Auduino
// More help: http://groups.google.com/group/auduino
//
// Analog in 0: Grain 1 pitch
// Analog in 1: Grain 2 decay
// Analog in 2: Grain 1 decay
// Analog in 3: Grain 2 pitch
// Analog in 4: Grain repetition frequency
//
// Digital 3: Audio out (Digital 11 on ATmega8)
//
// Changelog:
// 19 Nov 2008: Added support for ATmega8 boards
// 21 Mar 2009: Added support for ATmega328 boards
// 7 Apr 2009: Fixed interrupt vector for ATmega328 boards
// 8 Apr 2009: Added support for ATmega1280 boards (Arduino Mega)

#include <avr/io.h>
#include <avr/interrupt.h>

uint16_t syncPhaseAcc;
uint16_t syncPhaseInc;
uint16_t grainPhaseAcc;
uint16_t grainPhaseInc;
uint16_t grainAmp;
uint8_t grainDecay;
uint16_t grain2PhaseAcc;
uint16_t grain2PhaseInc;
uint16_t grain2Amp;
uint8_t grain2Decay;

// Map Analogue channels
#define SYNC_CONTROL         (4)
#define GRAIN_FREQ_CONTROL   (0)
#define GRAIN_DECAY_CONTROL  (2)
#define GRAIN2_FREQ_CONTROL  (3)
#define GRAIN2_DECAY_CONTROL (1)


// Changing these will also requires rewriting audioOn()

#if defined(__AVR_ATmega8__)
//
// On old ATmega8 boards.
//    Output is on pin 11
//
#define LED_PIN       13
#define LED_PORT      PORTB
#define LED_BIT       5
#define PWM_PIN       11
#define PWM_VALUE     OCR2
#define PWM_INTERRUPT TIMER2_OVF_vect
#elif defined(__AVR_ATmega1280__)
//
// On the Arduino Mega
//    Output is on pin 3
//
#define LED_PIN       13
#define LED_PORT      PORTB
#define LED_BIT       7
#define PWM_PIN       3
#define PWM_VALUE     OCR3C
#define PWM_INTERRUPT TIMER3_OVF_vect
#else
//
// For modern ATmega168 and ATmega328 boards
//    Output is on pin 3
//
#define PWM_PIN       3
#define PWM_VALUE     OCR2B
#define LED_PIN       13
#define LED_PORT      PORTB
#define LED_BIT       5
#define PWM_INTERRUPT TIMER2_OVF_vect
#endif

// Smooth logarithmic mapping
//
uint16_t antilogTable[] = {
  64830,64132,63441,62757,62081,61413,60751,60097,59449,58809,58176,57549,56929,56316,55709,55109,
  54515,53928,53347,52773,52204,51642,51085,50535,49991,49452,48920,48393,47871,47356,46846,46341,
  45842,45348,44859,44376,43898,43425,42958,42495,42037,41584,41136,40693,40255,39821,39392,38968,
  38548,38133,37722,37316,36914,36516,36123,35734,35349,34968,34591,34219,33850,33486,33125,32768
};
uint16_t mapPhaseInc(uint16_t input) {
  return (antilogTable[input & 0x3f]) >> (input >> 6);
}

// Stepped chromatic mapping
//
uint16_t midiTable[] = {
  17,18,19,20,22,23,24,26,27,29,31,32,34,36,38,41,43,46,48,51,54,58,61,65,69,73,
  77,82,86,92,97,103,109,115,122,129,137,145,154,163,173,183,194,206,218,231,
  244,259,274,291,308,326,346,366,388,411,435,461,489,518,549,581,616,652,691,
  732,776,822,871,923,978,1036,1097,1163,1232,1305,1383,1465,1552,1644,1742,
  1845,1955,2071,2195,2325,2463,2610,2765,2930,3104,3288,3484,3691,3910,4143,
  4389,4650,4927,5220,5530,5859,6207,6577,6968,7382,7821,8286,8779,9301,9854,
  10440,11060,11718,12415,13153,13935,14764,15642,16572,17557,18601,19708,20879,
  22121,23436,24830,26306
};
uint16_t mapMidi(uint16_t input) {
  return (midiTable[(1023-input) >> 3]);
}

// Stepped Pentatonic mapping
//
uint16_t pentatonicTable[54] = {
  0,19,22,26,29,32,38,43,51,58,65,77,86,103,115,129,154,173,206,231,259,308,346,
  411,461,518,616,691,822,923,1036,1232,1383,1644,1845,2071,2463,2765,3288,
  3691,4143,4927,5530,6577,7382,8286,9854,11060,13153,14764,16572,19708,22121,26306
};

uint16_t mapPentatonic(uint16_t input) {
  uint8_t value = (1023-input) / (1024/53);
  return (pentatonicTable[value]);
}


void audioOn() {
#if defined(__AVR_ATmega8__)
  // ATmega8 has different registers
  TCCR2 = _BV(WGM20) | _BV(COM21) | _BV(CS20);
  TIMSK = _BV(TOIE2);
#elif defined(__AVR_ATmega1280__)
  TCCR3A = _BV(COM3C1) | _BV(WGM30);
  TCCR3B = _BV(CS30);
  TIMSK3 = _BV(TOIE3);
#else
  // Set up PWM to 31.25kHz, phase accurate
  TCCR2A = _BV(COM2B1) | _BV(WGM20);
  TCCR2B = _BV(CS20);
  TIMSK2 = _BV(TOIE2);
#endif
}


void setup() {
  pinMode(PWM_PIN,OUTPUT);
  audioOn();
  pinMode(LED_PIN,OUTPUT);
}

void loop() {
  // The loop is pretty simple - it just updates the parameters for the oscillators.
  //
  // Avoid using any functions that make extensive use of interrupts, or turn interrupts off.
  // They will cause clicks and poops in the audio.

  // Smooth frequency mapping
  //syncPhaseInc = mapPhaseInc(analogRead(SYNC_CONTROL)) / 4;

  // Stepped mapping to MIDI notes: C, Db, D, Eb, E, F...
  //syncPhaseInc = mapMidi(analogRead(SYNC_CONTROL));

  // Stepped pentatonic mapping: D, E, G, A, B
  syncPhaseInc = mapPentatonic(analogRead(SYNC_CONTROL));

  grainPhaseInc  = mapPhaseInc(analogRead(GRAIN_FREQ_CONTROL)) / 2;
  grainDecay     = analogRead(GRAIN_DECAY_CONTROL) / 8;
  grain2PhaseInc = mapPhaseInc(analogRead(GRAIN2_FREQ_CONTROL)) / 2;
  grain2Decay    = analogRead(GRAIN2_DECAY_CONTROL) / 4;
}

SIGNAL(PWM_INTERRUPT)
{
  uint8_t value;
  uint16_t output;

  syncPhaseAcc += syncPhaseInc;
  if (syncPhaseAcc < syncPhaseInc) {
    // Time to start the next grain
    grainPhaseAcc = 0;
    grainAmp = 0x7fff;
    grain2PhaseAcc = 0;
    grain2Amp = 0x7fff;
    LED_PORT ^= 1 << LED_BIT; // Faster than using digitalWrite
  }

  // Increment the phase of the grain oscillators
  grainPhaseAcc += grainPhaseInc;
  grain2PhaseAcc += grain2PhaseInc;

  // Convert phase into a triangle wave
  value = (grainPhaseAcc >> 7) & 0xff;
  if (grainPhaseAcc & 0x8000) value = ~value;
  // Multiply by current grain amplitude to get sample
  output = value * (grainAmp >> 8);

  // Repeat for second grain
  value = (grain2PhaseAcc >> 7) & 0xff;
  if (grain2PhaseAcc & 0x8000) value = ~value;
  output += value * (grain2Amp >> 8);

  // Make the grain amplitudes decay by a factor every sample (exponential decay)
  grainAmp -= (grainAmp >> 8) * grainDecay;
  grain2Amp -= (grain2Amp >> 8) * grain2Decay;

  // Scale output to the available range, clipping if necessary
  output >>= 9;
  if (output > 255) output = 255;

  // Output to PWM (this is faster than using analogWrite) 
  PWM_VALUE = output;
}

Credits

CharisCat

Musician, video producer, and general tinkerer from Devon in the UK.

Shop

Project Hub

Video

Blog

Shop home

3D printing

Single Board Computers

Development kits

Sensors

Internet of things

Robotics

Accessories

Product of the Week

Electromaker Educator

The Electromaker Show

The Electromaker Podcast

Build A Granular Synthesiser Using The Arduino

About the project

Project info